ラベル MAXScript の投稿を表示しています。 すべての投稿を表示
ラベル MAXScript の投稿を表示しています。 すべての投稿を表示

2012年5月27日日曜日

MAXScript 文字列 コピー 置換

オブジェクト名に禁則文字が含まれていたので、エクスポート時に _で置換

文字列のコピーと置換のテスト


-- name に禁則文字 があったら rCh で置換する
fn ReplaceProhibitChar name rCh = (
  -- 禁則文字 仮
  prohibit = "\\/:,;*?\"<>|"

  -- 名前をコピーする
  newName = copy name
  
  -- 禁則文字を rCh に置換
  for j = 1 to prohibit.count do (
    for i = 1 to newName.count do (
      if prohibit[j] == newName[i] do (
        newName[i] = rCh
      )
    )
  )
  
  format "oldName %\n" name
  format "newName %\n" newName
  
  newName
)

str1 = ReplaceProhibitChar "aaa:0" "_"

2012年4月28日土曜日

MAXScript テキストファイルに書き出す

シーン内で使用しているテクスチャ画像の絶対パスをファイルに書き出す テスト

WriteDiffuseTexFilePath.ms

-- マテリアルのDiffuseテクスチャ画像の絶対パスをファイルに出力
fn WriteMtlInfo fs mtl = (
  d = mtl.DiffuseMap
  if undefined == d do return -2
  
  bm = d.bitmap
  if undefined == bm do return -3
  
  filePath = d.fileName
  
  -- ファイルの絶対パスを取得
  FileResolutionManager.getFullFilePath &filePath #Bitmap

  -- ¥ を /に変換
  strArray = filterString filePath "¥¥"
  filePath = ""
  for i = 1 to strArray.count do (
    filePath += strArray[i]
    if i < strArray.count do (
      filePath += "/"
    )
  )
  -- 画像の幅、高さ
  w = bm.width
  h = bm.height
  format "%¥n" filePath to:fs -- 絶対パスをファイルに出力
)

-- シーン内のマテリアル情報の取得
fn WriteDiffuseTexFilePath fileName = (
  if 0 == sceneMaterials.count do (
    format "sceneMaterials.count is 0¥n"
    return -1
  )

  -- ファイル出力先のディレクトリ
  fPath =  GetDir #export
  fPath += "¥¥" + fileName

  -- ファイルオープン
  fs = openFile fPath mode:"wt"
  if undefined  == fs do return -1
  
  for i = 1 to sceneMaterials.count do (
    mtl = sceneMaterials[ i ]   -- マテリアルを取得
    c = classof mtl     -- マテリアルのクラス名を取得

    if c == Standardmaterial do (
      WriteMtlInfo fs mtl
    )
    if c == Multimaterial do (
      nSubMtl = getNumSubMtls mtl -- マテリアルのサブマテリアル数を取得
      for j = 1 to nSubMtl do (
        subMtl = getSubMtl mtl j
        WriteMtlInfo fs subMtl
      )
    )
  )
  -- ファイルクローズ
  close fs  
)
-- exportフォルダにTexFilePath.txtが作成される
WriteDiffuseTexFilePath "TexFilePath.txt"

2012年4月23日月曜日

MAXScript マテリアル毎にノードをまとめる

FBXをインポートしてみたら、ノード数が多いので

sceneMaterialsを使って、マテリアル毎にまとめるテスト

MergeNodeTest.ms

g_NodeNameArray = #() -- シーン中のノード名の配列

-- 再帰関数でノードを列挙する
fn EnumNode n =
(
  for n in n.children do
  (
    -- 配列にノード名を追加
    append g_NodeNameArray n.name
    -- 再帰処理
    EnumNode n
  )
)

-- 文字列の配列から一致する文字列のインデックスを取得
fn GetNameIndex strArray str = (
  for i = 1 to strArray.count do (
    if strArray[i] == str do (  
      return i
    )
  )
  -1  -- 一致する文字列が無い
)

-- マテリアル毎にノードをまとめるテスト
fn MergeNodePerStdMtl = (
  -- シーン内のノード数
  format "Scene Node Num = %\n" g_NodeNameArray.count
  
  -- シーン内のマテリアル数を出力
  format "sceneMaterials.count %\n" sceneMaterials.count
  
  -- シーン内のスタンダードマテリアル名の配列
  strStdMtlNameArray = #()
  
  for mtl in sceneMaterials do (
    -- マテリアルのクラス名を取得
    c = classof mtl
--    format "mtl.name = % class = %\n" mtl.name c

    if c == Standardmaterial do (
      -- スタンダードなマテリアル名を追加
      append strStdMtlNameArray mtl.name  
    )
    
    if c == Multimaterial do (
      nSubMtl = getNumSubMtls mtl
--      format "nSubMtl = %\n" nSubMtl    -- サブマテリアル数
    )
  )
  
  -- strStdMtlNameArrayが空なので抜ける
  if strStdMtlNameArray.count == 0 do return 1

  -- スタンダードマテリアルを使用するノードの配列を作成
  stdMtlNodeArray = #()
  stdMtlNodeArray.count = strStdMtlNameArray.count
  
  -- シーン内のノードをスタンダードマテリアル毎にマージする
  for i = 1 to g_NodeNameArray.count do (
    -- ノードを名前から取得
    n = getNodeByName g_NodeNameArray[i]
    if undefined == n do continue
    
    -- ノードのマテリアルを取得
    mtl = n.material
    if undefined == mtl do continue
    
    c = classof mtl -- マテリアルのクラス
    if c == Standardmaterial do (
      -- 配列のインデックスを取得
      idx = GetNameIndex strStdMtlNameArray mtl.name
      if -1 == idx do continue
      
      if undefined == stdMtlNodeArray[ idx ] then (
        -- 空なので、ノードをセット
        stdMtlNodeArray[idx] = n
      )
      else (
        -- ノードをマージする
        stdMtlNodeArray[idx] = stdMtlNodeArray[idx] + n
        -- マージしたノードは削除
        delete n
      )
    )
  )
)

rn = rootNode       -- ルートノードを取得する
EnumNode rn         -- シーン内のノードを列挙
MergeNodePerStdMtl()  -- スタンダードなマテリアル毎にノードをマージ

2012年3月20日火曜日

MAXScript 形状のブール演算


-- メッシュのブール演算のテスト
fn Test5 = (
 -- 形状を作成
 s1 = box width:150 height:5
 
 s2 = sphere radius:20
 s2.pos.x = 50

 s3 = pyramid depth:55
 s3.pos.x = -50
 s3.pos.z = 2.5
 
 -- 減算
 s1 = s1 - s2
 
 -- 加算
 s1 += s3
 
 delete s2
 delete s3
 s1
)

Test5()

MAXScript 配列とビット配列


-- .NETオブジェクトの ArrayList を使用するテスト
fn TestArray1 = (
 -- .NET のArrayListオブジェクトを取得
 arrayList = dotNetObject "System.Collections.ArrayList"
 
 -- ArrayListに要素を追加
 arrayList.Add("A")
 arrayList.Add("BC")
 arrayList.Add("D")
 
 -- 配列の要素数を出力
 format "arrayList.Count = %\n" arrayList.Count
 
-- format "%\n" arrayList[1] -- ERROR
 
 str = arrayList.ToString()
 format "str = %\n" str
 
 item1 = arrayList.Item(1)
 format "%\n" item1
 
 for i = 0 to arrayList.Count - 1 do (
  --  ↓ ERROR発生
--  format "arrayList[%] = %\n" i arrayList[i] -- ERROR
  -- 指定したインデックスの要素を取得
  item = arrayList.Item(i)
  format "arrayList[%] = %\n" i item
 )

-- arrayList.Item(1) = "bc"
 
 item1 = arrayList.Item(1)
 format "item1 = %\n" item1

 for i = 0 to arrayList.Count - 1 do (
  --  ↓ get_Item()が出力される
  format "arrayList[%] = %\n" i arrayList.Item(i)
 )
)

-- 配列とビット配列のテスト
fn TestArray2 = (
 -- 空の配列を作成
 a = #()

 -- 配列に値を追加
 append a 1
 append a 2

 format "a = %\n" a

 -- 配列の要素を削除
 deleteItem a 2
 --deleteItem a 1

 format "a = % a.count = %\n" a a.count

 -- 空のビット配列を作成
 b0 = #{}
 b1 = #{}

 --b0[0] = true -- ERROR インデックスは1から開始
 b0[1] = false
 b0[20] = true
 b0[32] = true
 
 b1[8] = true

 format "b0 = % b0.count = %\n" b0 b0.count
 format "b1 = % b1.count = %\n" b1 b1.count
 
 b2 = b0 + b1 -- OR演算
 b3 = b0 * b1 -- AND演算
 
 format "b0 + b1 = %\n" b2
 format "b0 * b1 = %\n" b3
 
 b4 = -b1  -- ビットの反転
 format "-b1 = %\n" b4
 
 b1[20] = true
 b5 = b0 - b1 -- 差
 format "b0 - b1 = %\n" b5
 
 b6 = #{1..7, 16}
 format "b6 = % b6.numberSet = %\n" b6 b6.numberSet
)

TestArray2()

2012年3月4日日曜日

MAXScript OSMの読み込み (1)

OpenStreetMapのosmファイルを読み込んでメッシュを生成するテスト

2012年2月29日水曜日

MAXScript メッシュの作成(2)

ポリラインの作成

--  制御点の配列からポリラインを作成
fn CreatePolyLineFromPosArray posArray lineWidth = (

    ss = SplineShape pos:posArray[1]    -- posArray[1]にSplineShapeを作成
    idx = addNewSpline ss                   -- スプライン曲線を追加
    format "NewSpline idx = %\n" idx
    
    for i = 1 to posArray.Count do (
        addKnot ss idx #corner #line posArray[ i ]  
    )
    -- シェイプの更新
    updateShape ss  

    -- [ビューポートを有効]チェックボックスをオン
    ss.render_displayRenderMesh = true
    -- 矩形断面モードにする
--  ss.render_viewport_rectangular = true
    ss.render_rectangular = true

    -- 矩形断面の設定値
--  ss.render_length  = 5.0
    ss.render_width = lineWidth

--  ss.render_viewport_length = 1.0
--  ss.render_viewport_width = lineWidth
    
    -- メッシュに変換
    convertToMesh ss
    format "ss.numfaces %\n" ss.numfaces
    
    -- アップベクトル
    vUp = [0, 0, 1]
    -- 削除する面のインデックスの配列
    faceIdxArray = #()
    
    for f = 1 to ss.numfaces do (
        -- 面の法線を取得
        n = getFaceNormal ss f
        -- アップベクトルと面の法線の内積
        d = dot vUp n
    
--      if d <= 0.0 do (        -- 削除されない面がある
        if d <= 0.01 do (       
            -- 削除する面のインデックスを追加
            append faceIdxArray f
        )
    )
    
    -- 道路以外のメッシュを削除
    meshop.deleteFaces ss faceIdxArray delIsoVerts:false
    
    -- UVWMapモディファイアの追加
    -- maptype 0 - 6
    addModifier ss (UVWMap maptype:5) -- maptype 0:Planar 4:Box 5: Face
    ss
)
-- CreatePolyLineFromPosArrayのテスト
-- 制御点の配列
gPosArray1 = #()
gPosArray2 = #()
-- 制御点を追加
append gPosArray1 [0, 0, 0] 
append gPosArray1 [200, 0, 0]
append gPosArray1 [200, 50, 0]
append gPosArray1 [250, 250, 0]
append gPosArray1 [300, 450, 0]
append gPosArray1 [50, 500, 0]

append gPosArray2 [0,  -50, 0]  
append gPosArray2 [0, 100, 0]

-- 線の幅
lineWidth = 25.0

-- メッシュを作成
newSpline1 = CreatePolyLineFromPosArray gPosArray1 lineWidth
classof newSpline1
newSpline2 = CreatePolyLineFromPosArray gPosArray2 lineWidth

-- メッシュの加算
newSpline1 = newSpline1 + newSpline2
-- 追加したメッシュを削除
delete newSpline2

2012年2月18日土曜日

MAXScript メッシュの作成 (1)

SplineShapeを作成 -> 押し出して何かするテスト

-- 制御点の配列
gPosArray = #()
append gPosArray [20,  10,  0]
append gPosArray [20, -10, 0]
append gPosArray [-20,-20, 0]
append gPosArray [-20, 25, 0]

-- シンプルなメッシュの作成
-- SplineShapeを作成して押し出す
-- posArray 制御点の配列
-- Height       SplineShapeを押し出す高さ
-- Outline      輪郭の押し出し値
fn CreateSimpleMesh posArray Height Outline= (
    
    -- SplineShapeを作成
    local sp = splineShape()
    idx = addnewSpline sp
    for i = 1 to posArray.Count do (
        addKnot sp idx #corner #line posArray[ i ]
    )
    close sp idx
    updateShape sp

    -- メッシュに変換
    convertToMesh sp

    -- 全面の押し出し
    meshop.extrudeFaces sp #{ 1.. sp.numfaces } Height Outline

    -- メッシュの面のマテリアルIDを変更
    newMtlID = 2
    setFaceMatID sp 1 newMtlID  -- Face 1
    setFaceMatID sp 2 newMtlID  -- Face 2
/*  
    -- 面のマテリアルIDを取得
    for i = 1 to sp.numfaces do (
        format "Face % Mtl ID = %\n" i ( getFaceMatID sp i )
    )
*/
    -- UVWMapモディファイアの追加
    addModifier sp (UVWMap maptype:4) -- maptype 4:Box
    
    sp
)

-- メッシュを作成
mesh1 = CreateSimpleMesh gPosArray 100.0 -2.0
mesh1.pos = [100, 0, 0]

mesh2 = CreateSimpleMesh gPosArray 50.0 0.0
mesh2.pos = [0, 50, 0]

mesh3 = CreateSimpleMesh gPosArray 25.87 15.0
mesh3.pos = [-50, -80, 0]

MAXScript ストリングストリーム

StringStream

-- テストその1
fn TestStringStream1 = (
    -- 空のStringStreamを作成
    ss1 = stringStream ""
--  ss1 = stringStream      -- ERROR
    
    -- ss1に出力
    format "ABC %" "123456789" to:ss1
    
    -- シーク位置を先頭にする
    seek ss1 0
    -- 読み込んだ行を出力   シーク位置が進む
    format "%\n" ( readLine ss1 )
    
    -- ストリームの終了チェック
    isEnd = eof ss1
    format "isEnd = %\n" isEnd  -- true
)

-- テストその2
fn TestStringStream2 = (
    -- .NETクラスを取得
    dnDayTime = dotNetClass "System.DateTime"
    dnTimeZone = dotNetClass "System.TimeZone"
    
    -- 日付を取得
    currentDate = dnDayTime.Now
    currentYear = currentDate.Year

    -- 空のStringStreamを作成
    ss = stringStream ""

    -- ssに書き込む
    format "Current Year = %\n" currentYear to:ss
    format "Month = %\n" currentDate.Month to:ss
    format "Day = %" currentDate.Day to:ss
    
    -- ssの内容を出力
    seek ss 0
    while not eof ss do (
        format "%\n" (readLine ss)
    )

--  print (readLine ss)
--  while not eof ss do print ( readLine ss )
)

TestStringStream1()
TestStringStream2()

2012年2月17日金曜日

MAXScript マテリアルエディタの操作 (2) マルチ


マルチマテリアルを作成するスクリプト

・作成するスロット番号を選択
・サブマテリアル数を選択
・Createボタンを押す
・画像選択ダイアログで画像選択


-- dropdownlist作成用の配列
slotNoArray = #()
subMtlNumArray = #()

-- デフォルト値
defaultSlotNo = 1           -- スロット番号
defaultSubMtlNum = 2        -- サブマテリアル数

-- 初期化処理
fn Init = (
    -- スロット番号
    for i = 1 to 24 do (
        append slotNoArray ( i as string )
    )
    -- サブマテリアル数
    for i = 1 to 10 do (
        append subMtlNumArray ( i as string )
    )
)

-- マルチマテリアルを作成
-- slotNo: スロット番号
-- subMtlNum: サブマテリアル数
fn CreateMultiMtl slotNo subMtlNum = (

    -- モードのセット
    MatEditor.mode = #basic

    -- 状態取得
    isOpen = MatEditor.isOpen()
    
    -- マテリアルエディタを開く
    if false == isOpen do ( MatEditor.Open() )

    -- マルチマテリアルを作成
    newMtl = multimaterial ()
    
    -- 画像を読み込む
    for i = 1 to subMtlNum do (
        -- Captionの文字列
        ss = stringStream ""
        format "Select SubMtl Texture %" i to:ss
        seek ss 0
        str = ( readLine ss )

        -- 画像を選択
        local img = selectBitMap caption:str
        if undefined == img do ( return undefined )
        
        -- 選択画像からBitmapTextureを作成
        local bmTex = BitmapTexture bitmap:img

        -- マテリアルを作成
        local mtl = standardMaterial diffuseMap:bmTex showInViewport:true
        
        newMtl[i] = mtl
    )
    -- マテリアルをスロットにセット
    setMeditMaterial slotNo newMtl
)
-- ロールアウト
rollout RolloutMtl "CreateMultiMaterial" 
(
    -- スロット数選択用
    dropdownlist dSlotNo "Slot No:" pos:[16, 16] \
            items:slotNoArray width:80

    -- サブマテリアル数選択用
    dropdownlist dNumSubMtl "Sub Material Num:" pos:[120, 16] \
            items:subMtlNumArray width:80 selection:defaultSubMtlNum

    -- 作成ボタン
    button btnCreate "Create" width:96 height:24    pos:[64, 64]
    
    on  btnCreate pressed do (
        CreateMultiMtl dSlotNo.selection dNumSubMtl.selection
    )
)
Init()
createDialog RolloutMtl width:240 height:100

MAXScript マテリアルエディタの操作 (1)


-- マテリアルエディタの操作テスト
fn TestMedit = (
    -- モード取得
    format "Medit mode = %\n" MatEditor.mode
    
    -- マテリアルエディタを開く
    MatEditor.Open()
    
    isOpen = MatEditor.isOpen()
    format "isOpen = %\n" isOpen
    
    -- スロットからマテリアルを取得
    
    mtl1 = getMeditMaterial 1
    format "mtl1.name = %\n" mtl1.name

    -- マテリアルのプロパティの変更
    mtl1.diffuse = yellow
    
    
    -- スロットにマテリアルを設定
    
    -- 画像を読み込む
    img = selectBitMap ()
    if undefined == img do return undefined

    -- 選択画像からBitmapTextureを作成
    bmTex = BitmapTexture bitmap:img

    -- スロットにマテリアルをセット
    newMtl = standardMaterial diffuseMap:bmTex
    setMeditMaterial 2 newMtl

    format "newMtl.name = %\n" newMtl.name
    
--  newMtl = standardMaterial diffuseMap:( checker() )
--  setMeditMaterial 3 newMtl

    -- マテリアルエディタを閉じる
--  MatEditor.Close()
)

TestMedit()

2012年2月15日水曜日

MAXScript xmlのテスト

dotNetObjectを使う

-- Xml Test 文字列
xmlString = "<?xml version=\"1.0\" encoding=\"UTF-8\"?>
   <rootElem ver = \"2.1\">
    <childElemA str = \"A\" num = \"123\"/>
    <childElemA str = \"A\" num = \"456\"/>
    <childElemB str = \"B\"/>
   </rootElem>"

-- XmlElementの属性値を取得
fn GetAttrib elem elemName = (
 if true == elem.HasAttribute( elemName ) then (
  return elem.GetAttribute( elemName )
 )
 return undefined
)


-- System.Xml.XmlDocument オブジェクトを作成
xmlDoc = dotNetObject "System.Xml.XmlDocument"
xmlDoc.LoadXml xmlString  -- 文字列からXMLを読み込む
xmlDoc.LocalName

-- ルートXmlElementを取得
rootElem = xmlDoc.DocumentElement

-- 属性値を取得
GetAttrib rootElem "ver"   -- "2.1"
GetAttrib rootElem "Ver"   -- undefined

-- 子ノードの属性値を取得
elemList = rootElem.GetElementsByTagName("childElemA");
for i = 1 to elemList.Count do (
 n = elemList.ItemOf (i - 1)  -- ノードを取得
 format "v = %\n" ( GetAttrib n "num" )
 format "v = %\n" ( GetAttrib n "Num" )  -- undefined
)

2012年2月11日土曜日

MAXScript ノードのプロパティを変更


/*
 vFromベクトルからvToベクトルまでの角度を取得
*/
fn GetAngle vFrom vTo =
(
 vFrom = normalize vFrom
 vTo = normalize vTo
 
 rotDot = dot vFrom vTo
 
 rotAngle = acos rotDot -- 角度は度
)

/*
 座標がノードの右側に位置するか判定

 nodeMtx ノードの行列
 pos 判定する座標
*/
fn IsRightSide nodeMtx pos =
(
 toPos = pos - nodeMtx.translation
 right = -nodeMtx.row1 -- ノードのRightベクトル
 
 d = dot right toPos
 if d > 0.0 do ( return true )
 return false
)

-- MAXWrapperのプロパティを変更するテスト
fn Test1 =
(
 -- ターゲット 
 target = mesh vertices:#([0,0,0],[10,0,40],[-10,0,40]) \
     faces:#([1,2,3]) materialIDS:#(1)
 target.pos = [-25, 75, 0]
 target.name = "Target"
 
 -- オブジェクトの作成
 -- 三角形のメッシュを作成
 tri = mesh vertices:#([0,-20,0],[10,10,0],[-10,10,0]) \
     faces:#([1,2,3]) materialIDS:#(1)

 -- オイラー角を作成
 rotAngle = eulerAngles 0.0 0.0 -45.0

 -- 回転の変更
-- tri.rotation = rotAngle as quat

 -- 位置の変更
 tri.pos = [0, 0, 0]

 -- スケールの変更
 tri.scale = [1, 2, 1]

 -- 選択状態の変更
 tri.isSelected = true

 -- ノードの行列
 format "mtx %\n" tri.transform
 
 -- ノードのローカルのZ方向
 format "dir %\n" tri.dir
 
 -- オブジェクトからターゲットまでのベクトル
 vToTarget = target.pos - tri.pos
 
 -- オブジェクトの進行方向
 vFwd = -tri.transform.row2
 
 -- ターゲットに向ける角度を取得
 rotAngle = GetAngle vFwd vToTarget
 format "rotAngle %\n" rotAngle
 
 -- ターゲットの座標がオブジェクトの右側か判定
 isRight = IsRightSide tri.transform target.pos
 format "isRight %\n" isRight
 
 if isRight == false do ( rotAngle = -rotAngle )
 
 -- オブジェクトの正面がターゲットを向くように回転させる
 rotAngle = eulerAngles 0.0 0.0 rotAngle
 tri.rotation = rotAngle as quat 
)

Test1()

2012年1月31日火曜日

MAXScript ハイトマップからメッシュの作成(1)

Bmp, Jpeg画像のハイトマップから地形を作成するスクリプト

-- ビットマップ
gBitmap = undefined
-- 平面のサイズ
gPlaneSizeX = 500.0
gPlaneSizeY = 500.0
-- 平面のセグメント数
gNumSegX = 25
gNumSegY = 25
-- 最大の高さ
gHeightMax = 25.0

-- メッシュの作成
fn CreatePlaneMesh len wid segX segY = 
(
 m = mesh length:len width:wid lengthsegs:segY widthsegs:segX
 return m
)

-- セグメントのインデックスからピクセルのインデックスを取得
fn GetPixIdx segIdx segNum pixNum =
(
 segIdxF = segIdx as float
 segNumF = segNum as float
 
 f = segIdxF / segNumF
 pixIdx = f * (pixNum - 1)
 return pixIdx as integer
)

-- メッシュの指定したインデックスの頂点に高さをセット
fn SetHeight m idx height =
(
 v = patch.getVert m idx
 v.z = height
 patch.setVert m idx v
)

-- メッシュにハイトマップの高さをセット
fn Mesh_SetHeightMap m nSegX nSegY bm =
(
 -- 高さをセットするメッシュの頂点のインデックス
 idx = 1
 bmWidth = bm.width
 bmHeight = bm.height

 for y = 0 to nSegY do (
  pixY = GetPixIdx y nSegY bmHeight
  pixY = pixY as integer

  for x = 0 to nSegX do (
   pixX = GetPixIdx x nSegX bmWidth
   pixX = pixX as integer
   
   -- ビッドマップからピクセルの配列を取得
   pixArray = getPixels bm [pixX, pixY] 1
   
   -- 高さ
   h = pixArray[1].r / 255.0
   h = h * gHeightMax
   
   SetHeight m idx h
   idx = idx + 1
  )
 )
)

-- ハイトマップからメッシュを作成
fn CreateMeshFromHeightmap =
(
 -- ハイトマップを開く
 fPath = getOpenFileName caption:"Open Heightmap:" \
  types:"Bmp(*.bmp)|*.bmp|Jpeg(*.jpg)|*.jpg"
 if fPath == undefined then return -1

 gBitmap = openBitMap fPath
 format "w = % h = %\n" gBitmap.width gBitmap.height

 -- メッシュを作成
 m = CreatePlaneMesh gPlaneSizeX gPlaneSizeY gNumSegX gNumSegY
 
 -- パッチに変換
 convertTo m Editable_Patch
 
 -- 高さをセット
 Mesh_SetHeightMap m gNumSegX gNumSegY gBitmap
)
-- テスト
CreateMeshFromHeightmap()

MAXScript ビットマップの作成


-- ビットマップサイズ
gBitmapWidth = 256
gBitmapHeight = 8

-- グラデーションビットマップを作成
fn CreateGradBitmap =
(
 b_width = gBitmapWidth
 b_height = gBitmapHeight
 
 -- ビットマップを作成
 b = bitmap b_width b_height

 -- 列のループ
 for h = 0 to (b_height - 1) do
 (
  -- 行のピクセル配列を収集
  row = for w = 0 to (b_width - 1) collect
  (
   -- 補間係数
   t = w as float / (b_width - 1)
   
   -- rowにカラー値を追加
   if undefined != gSpline then
   (
    -- スプラインから座標を取得
    pos = interpCurve3D gSpline gSplineIdx t
    white * (pos.y / 100.0)
   )else (
    white * t
   )
  )
  -- 収集したピクセル配列をセット
  setpixels b [0, h] row
 )
 return b
)

-- ビットマップを作成
b = CreateGradBitmap()
-- ビットマップを表示
if undefined != b then display b

MAXScript ベジェ曲線の作成


gSpline = undefined
gSplineIdx = 0

-- スプラインシェイプを作成
fn CreateSpline =
(
 if undefined != gSpline then return -1 
 
 -- シェイプの作成
 ss = splineShape()
 -- シェイプにスプライン曲線を追加
 idx = addnewSpline ss

 -- addKnotのパラメータ
 param3 = #bezier 
 param4 = #curve

 -- bezier曲線の制御点のイン、アウトベクトルの座標
 inPos0 = [0, 0, 0]
 outPos0 = [0, 0, 0]
 inPos1 = [30, 10, 0]
 outPos1 = [70, 40, 0]
 inPos2 = [100, 100, 0]
 outPos2 = [100, 100, 0]

 -- 制御点の追加
 addKnot ss idx param3 param4 [0, 0, 0] inPos0 outPos0
 addKnot ss idx param3 param4 [50, 20, 0] inPos1 outPos1
 addKnot ss idx param3 param4 [100, 100, 0] inPos2 outPos2
 
 -- シェイプの更新
 updateShape ss
 
 -- コピー
 gSpline = ss
 gSplineIdx = idx
 return 0
)

-- 形状データ取得テスト
fn GetShapeDataTest ss idx =
(
 -- セグメント数
 nSeg = numSegments ss idx
 format "nSeg %\n" nSeg
 
 -- 曲線の座標
 for t = 0.0 to 1.0 by 0.1 do
 (
  pos = interpCurve3D ss idx t
  format "t = % pos = %\n" t pos
 )
)

CreateSpline()
GetShapeDataTest gSpline gSplineIdx

2012年1月28日土曜日

MAXScript ルートボーンの移動アニメを変更してみる(2)

あるモデルのルートボーンの移動アニメを無効にしたい
/*
 選択したボーンの全フレームの座標変更
 pos: セットする座標

    使用方法
 トラックビュー選択ダイアログが表示されるので
 変更したいボーンの"Transform : Position/Rotation/Scale"
 を選択してOKボタンを押す
 */
fn SetSelectBonePosAllKey pos =
(
 -- ダイアログ表示オプション
 dlgOpt = 0
 dlgOpt = bit.set dlgOpt 1 true --アニメトラックのみ
-- dlgOpt = bit.set dlgOpt 3 true   --選択したノードのみ

 -- ダイアログを表示
 tvp = trackview.pickTrackDlg options:dlgOpt

 if tvp == undefined then return -1 -- 未選択
 
 format "tvp.name %\n" tvp.name -- 選択した項目の名前
 if "Transform" != tvp.name then return 1
 
 c0 = tvp.client -- 選択項目の親のMAXWrapper
 if c0 != undefined then
 (
  cname = getClassName c0
  format "c0.className %\n" cname
  if cname != "Bone" then return 2
 )
 
 -- 選択項目のサブアニメを取得
 subAni = tvp.anim
 if subAni == undefined  then return 3

 -- サブアニメ数
 format "subAni.numSubs %\n" subAni.numSubs
 ret = 4
 for i = 1 to subAni.numSubs do
 (
  -- サブアニメの名前
  n =  getSubAnimName subAni i
  format "subAnim name %\n" n

  -- Positionのみ変更
  if 0 != stricmp n "position" then continue
   
  -- コントローラーの取得
  c = subAni[i].Controller
  if c == undefined  then continue

  -- コントローラーからキーの配列を取得
  keys = c.keys
  -- キーフレーム数
  format "key_array count %\n" keys.count
    
  -- 全キーフレームの座標を変更
  for j = 1 to keys.count do
  (
   keys[j].value = pos
  )
  ret = 0
 )
 return ret
)

gPos = [0, 0, 0] -- セットする座標
SetSelectBonePosAllKey gPos

2012年1月27日金曜日

ghostTown

街生成スクリプトが 0.31にバージョンアップしていた
以前のバージョンを実行、使い方が?? ど忘れ・・・

Show Guideボタンでガイド表示
平面などを配置して
Setupボタン -> Buildボタンで街生成

生成結果

エラーが出る場合、Materialタブの Update GTMatLibボタンを押す

描画結果

2012年1月26日木曜日

MAXScript ノードの列挙


g_tabnum = 0    -- タブ数

-- タブ文字列を取得する num: タブ数
fn GetTab num = 
(
 t = ""
 for i = 1 to num do
 (
  t += "\t"
 )
 return t
)

-- 再帰関数でノードを列挙する
fn EnumNode n =
(
 t = GetTab g_tabnum
 g_tabnum += 1
 
 for n in n.children do
 (
  -- クラス名の取得
  cname = getClassName n
--  format "%className: %\n" t cname
  if cname == "Bone" then
  (
   -- ボーン名を出力する
   format "%boneName: %\n" t n.name
  )
  
  EnumNode n  -- 再帰処理
 )
 g_tabnum -= 1
)

-- ノードの列挙
EnumNode rootNode

MAXScript ファイルにバイナリ形式のデータを書き出す


-- Floatの大きな値
BIG_FLOAT = 1.0e32

-- AABB
struct AABB
(
 vMin,
 vMax
)

-- AABBを取得
fn GetAABB =
(
 local v = AABB()
 v.vMin = [ BIG_FLOAT, BIG_FLOAT, BIG_FLOAT ]
 v.vMax = [-BIG_FLOAT, -BIG_FLOAT, -BIG_FLOAT]
 return v
)

-- binStreamにPoint3を書き込む
fn WritePoint3 bstream v =
(
 WriteFloat bstream v.x
 WriteFloat bstream v.y
 WriteFloat bstream v.z
)

-- ファイルにAABBの値を書き込む
fn WriteAabbToFile filePath aabb =
(
 file = fopen filePath "wb"
 
 WritePoint3 file aabb.vMin
 WritePoint3 file aabb.vMax 
 
 fclose file
)


-- ファイルにデータを書き込むテスト
fname = "test.bin"   -- ファイル名
fdir = (GetDir #export)  -- ファイルを書き込むディレクトリ

fpath = fdir + "\\" + fname

aabb = GetAABB()

aabb.vMin.x = 8.0
aabb.vMax.z = 0.0

WriteAabbToFile fpath aabb